Visual Basic Foro

Programación => Visual Basic 6 => Mensaje iniciado por: Cymas en Enero 06, 2015, 10:41:35 pm

Título: Hacer Zoom en un form o picture??
Publicado por: Cymas en Enero 06, 2015, 10:41:35 pm

Tal y como dice la pregunta hay alguna forma de hacer una especie de zoom en un formulario en vb6, lo que necesito es que el usuario pueda aumentar o reducir el tamaño de los controles que se encuentran en una ventana (son mayormente textbox y labels) y en si de todo lo contenido en un picture y que esta acción también también afecte al tamaño de lo que se va a imprimir supongo que para esto es mejor colocar todo en un control picture.

Para esta idea que tengo, no tengo ni una sola idea... ;D :P

en fin algo de código por favor..............

Título: Re:Hacer Zoom en un form o picture??
Publicado por: LeandroA en Enero 07, 2015, 02:11:46 am

Hola, creo que lo mejor seria hacer una captura del picture en cuestion y tratarlo como una imagen, podes usar las apis GetDC, StretchBlt  o PrintWindow, no se si estas familiarizado con el uso de apis.

Saludos.

Título: Re:Hacer Zoom en un form o picture??
Publicado por: AxioUK en Enero 07, 2015, 02:39:56 pm

Cymas: lo que quieres es poder aumentar el tamaño de los controles en tiempo de ejecución tal como lo hace Softland; o solo hacer un zoom del formulario? Softland implementa en sus pantallas un control deslizador con el que se puede ampliar el tamaño de GUI en tiempo de ejecución para personas con problemas visuales. hay un Usercontrol ucAnchor que autoposiciona los controles dentro de un form cuando modificas el tamaño, con unos retoque podrias acomodarlo a lo que necesitas, dejame ver si puedo hacer algo esta tarde y lo publico mañana temprano, pues ahora estoy algo liado con una actualización que debo entregar mañana. (jé)

<-EDITADO------------------------->
JaJa... Al parecer el control ya hace eso de ajustar el tamaño automáticamente al hacer Resize al Form...
te dejo el Link...

http://www.planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=75387&lngWId=1 (http://www.planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=75387&lngWId=1)



Saludos Cordiales

Título: Re:Hacer Zoom en un form o picture??
Publicado por: Cymas en Enero 08, 2015, 12:54:18 am

Creo que me interesa mas lo de las apis y aunque conozco algunas podrían explicarme como hacerlo de esta forma.
si para esto es necesario colocar otro control picture o image o en que pongo lo imagen que se haya capturado, de tal forma que pueda imprimirlo y a la vez poder guardarlo en un archivo .jpg o .bmp o algo similar.

y como hago el zoom con la captura??

es que soy relativamente nuevo, y es mi primer proyecto algo grande.

Por cierto hay algún tema que trate de esto un link porfa, no he encontrado mayor información al respecto...

Gracias a todos por su tiempo y su colaboración. :)  :)

Título: Re:Hacer Zoom en un form o picture??
Publicado por: Albertomi en Enero 08, 2015, 03:22:57 am

Estimado Cymas


Estos link te puede ser de tu interes
  http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=74026&lngWId=1 (http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=74026&lngWId=1)
  http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=68509&lngWId=1 (http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=68509&lngWId=1)
  http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=56729&lngWId=1 (http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=56729&lngWId=1)



Saludos, desde algún lungar de Lima-Perú

Título: Re:Hacer Zoom en un form o picture??
Publicado por: LeandroA en Enero 11, 2015, 09:57:41 pm

Hola nuevamente, segun entiendo tu deseo es imprimir un control con sus controles y pode establecer un zoom, ademas y o tambien poder obtener una imagen para guardarla en disco.

bien esta funcion te va a servir.
pega esto en un modulo, o en el formulario si lo prefieres.

Código: (vb) [Seleccionar]

Option Explicit

Private Type GUID
    Data1 As Long
    Data2 As Integer
    Data3 As Integer
    Data4(7) As Byte
End Type

Private Type PicBmp
    Size As Long
    Type As Long
    hBmp As Long
    hPal As Long
    Reserved As Long
End Type

Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type

Private Declare Function GetDC Lib "user32.dll" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseDC Lib "user32.dll" (ByVal hwnd As Long, ByVal hdc As Long) As Long
Private Declare Function PrintWindow Lib "user32.dll" (ByVal hwnd As Long, ByVal hdcBlt As Long, ByVal nFlags As Long) As Long
Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" (PicDesc As PicBmp, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function CreateCompatibleBitmap Lib "gdi32" (ByVal hdc As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function GetWindowRect Lib "user32.dll" (ByVal hwnd As Long, ByRef lpRect As RECT) As Long
Private Declare Function SetStretchBltMode Lib "gdi32.dll" (ByVal hdc As Long, ByVal nStretchMode As Long) As Long
Private Declare Function StretchBlt Lib "gdi32.dll" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal nSrcWidth As Long, ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long
Private Declare Function DeleteObject Lib "gdi32.dll" (ByVal hObject As Long) As Long


Function GetPictureControl(oControl As Object, Zoom As Integer) As Picture
    Dim hdc As Long
    Dim hDCMemory As Long, hBmp As Long, hBmpPrev As Long
    Dim hDCMemory2 As Long, hBmp2 As Long, hBmpPrev2 As Long
    Dim tRect As RECT
    Dim lWidth As Long, lHeight As Long
    Dim NewWidth As Long, NewHeight As Long
    Dim Pic As PicBmp, IPic As IPicture, IID_IDispatch As GUID
   
    GetWindowRect oControl.hwnd, tRect
   
    lWidth = tRect.Right - tRect.Left
    lHeight = tRect.Bottom - tRect.Top
   
    hdc = GetDC(0)
    hDCMemory = CreateCompatibleDC(0)
    hBmp = CreateCompatibleBitmap(hdc, lWidth, lHeight)
    hBmpPrev = SelectObject(hDCMemory, hBmp)

    PrintWindow oControl.hwnd, hDCMemory, 0

   
    NewWidth = (lWidth * Zoom / 100)
    NewHeight = (lHeight * Zoom / 100)

    hDCMemory2 = CreateCompatibleDC(0)
    hBmp2 = CreateCompatibleBitmap(hdc, NewWidth, NewHeight)
    hBmpPrev2 = SelectObject(hDCMemory2, hBmp2)
   
    SetStretchBltMode hDCMemory2, vbPaletteModeNone
    StretchBlt hDCMemory2, 0, 0, NewWidth, NewHeight, hDCMemory, 0, 0, lWidth, lHeight, vbSrcCopy
   
    ReleaseDC 0, hdc
   
    DeleteObject SelectObject(hDCMemory, hBmpPrev)
    Call DeleteDC(hDCMemory)

    Call SelectObject(hDCMemory2, hBmpPrev2)
    Call DeleteDC(hDCMemory2)

    With IID_IDispatch
        .Data1 = &H20400
        .Data4(0) = &HC0
        .Data4(7) = &H46
    End With


    With Pic
        .Size = Len(Pic)
        .Type = vbPicTypeBitmap
        .hBmp = hBmp2
    End With

    Call OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)

    Set GetPictureControl = IPic
   
   
End Function

y luego por ejemplo si queres imprimir el contenido de picture1 o obtener la imagen con zoom

Código: (vb) [Seleccionar]

Private Sub Command1_Click()
    Me.Picture = GetPictureControl(Picture1, 150)
End Sub

Private Sub Command2_Click()
    Printer.PaintPicture GetPictureControl(Picture1, 200), 0, 0
    Printer.EndDoc
End Sub