Visual Basic Foro

Programación => Visual Basic 6 => Mensaje iniciado por: Bazooka en Mayo 18, 2011, 04:42:55 pm

Título: Como obtener Nombre de PC y Usuario actual en SEVEN
Publicado por: Bazooka en Mayo 18, 2011, 04:42:55 pm

Hola necesito obtener el nombre del usuario actual, y el nombre de la pc en Windows 7 y Vista.

Alguien sabe?

Tambien me gustaria saber si hay alguna forma de obtener los datos de la MAC desde estos SO que mencione antes.

Gracias

Mike

Título: Re:Como obtener Nombre de PC y Usuario actual en SEVEN
Publicado por: Juan Luis López en Mayo 18, 2011, 08:38:31 pm

Para el nombre de usuario usa Environ y para la mac seguro que con getadaptersinfo puedes

Título: Re:Como obtener Nombre de PC y Usuario actual en SEVEN
Publicado por: LeandroA en Mayo 19, 2011, 06:32:46 am

Hola aca tenes dos codigos con api, para el usuario y  para la Mac

Código: [Seleccionar]

Option Explicit
Private Declare Function GetUserNameA Lib "advapi32.dll" (ByVal lpBuffer As String, nSize As Long) As Long

Private Sub Form_Load()
    MsgBox GetUserName
End Sub

Public Function GetUserName() As String
    Dim sBuff As String
    sBuff = String(100, Chr$(0))
    Call GetUserNameA(sBuff, 100)
    GetUserName = Left$(sBuff, InStr(sBuff, Chr$(0)) - 1)
End Function


Código: [Seleccionar]

'---------------------------------------------------------------------------------------
' Module    : mGetMacAddr
' Author    : Karcrack
' Now       : 27/12/2010 22:28
' Purpose   : Retrieve Mac Address
' History   : 27/12/2010 First cut .....................................................
' Reference : http://www.codeguru.com/cpp/i-n/network/networkinformation/article.php/c5451
'---------------------------------------------------------------------------------------
Option Explicit
'RPCRT4
Private Declare Function UuidCreateSequential Lib "RPCRT4" (ByRef tUUID As UUID) As Long

Private Type UUID
   a        As Currency
   b        As Integer
   c(5)     As Byte
End Type

Public Function GetMacAddr() As String
    Dim tUUID   As UUID
   
    Call UuidCreateSequential(tUUID)
    GetMacAddr = Hex$(tUUID.c(0)) & "-" & Hex$(tUUID.c(1)) & "-" & Hex$(tUUID.c(2)) & _
                 "-" & Hex$(tUUID.c(3)) & "-" & Hex$(tUUID.c(4)) & "-" & Hex$(tUUID.c(5))
End Function

Título: Re:Como obtener Nombre de PC y Usuario actual en SEVEN
Publicado por: Bazooka en Mayo 20, 2011, 12:10:32 am

Gracias Leando sos un CApo!! siempre tienes una respuesta justa!!

Título: Re:Como obtener Nombre de PC y Usuario actual en SEVEN
Publicado por: lucius en Mayo 20, 2011, 07:43:39 pm

Yo tengo este codigo para obtener el MAC pero solo probado con winXP y me gustaria saber si funciona en windows 7 y cual es la diferencia, en fin igual me quedo con el code de leandro jeje

Código: [Seleccionar]

Public Function leerIDcomputadora() As String

    Dim colNetAdapters, objWMIService As Object

    Dim strComputer As String

    strComputer = "."

    Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colNetAdapters = objWMIService.ExecQuery("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")

    For Each objitem In colNetAdapters

        leerIDcomputadora = objitem.MACAddress
    Next

End Function


Private Sub Command1_Click()
MsgBox "El MAC de esta Pc es " & leerIDcomputadora
End Sub