Posicion del Msgbox

[YAcosta]

Alguien sabe como hacer para que la ventana que invoca el Msgbox salga en las coordenadas de pantalla que yo desee? Quiero evitar usar un form propio.

Gracias

[xkiz ™]

podrías probar con MessageBoxIndirect MSGBOXPARAMS
pero no estoy muy seguro así que es solo una sugerencia, investigalo vos...

[YAcosta]

Gracias, revise las paginas, me queda un poco grande el saco, si ese es el único camino... creo que mas fácil me sera usar un form propio.

Saludos.

[E N T E R]

En un Modulo esto:

Código: [Seleccionar]

Type RECT
   Left As Long
   Top As Long
   Right As Long
   Bottom As Long
End Type

Public Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Public Declare Function GetCurrentThreadId Lib "kernel32" () As Long
Public Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
Public Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Public Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long

Public Const GWL_HINSTANCE = (-6)
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOZORDER = &H4
Public Const SWP_NOACTIVATE = &H10
Public Const HCBT_ACTIVATE = 5
Public Const WH_CBT = 5

Public hHook As Long

Function WinProc1(ByVal lMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

   If lMsg = HCBT_ACTIVATE Then
      'Show the MsgBox at a fixed location (0,0)

      'ACA LE CAMBIAS LA POSICION EL 100 Y EL 200 ES

      SetWindowPos wParam, 0, 100, 200, 0, 0, SWP_NOSIZE Or SWP_NOZORDER Or SWP_NOACTIVATE
      'Release the CBT hook
      UnhookWindowsHookEx hHook
   End If
   WinProc1 = False

End Function

Function WinProc2(ByVal lMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

    Dim rectForm As RECT, rectMsg As RECT
    Dim x As Long, y As Long
   
    'On HCBT_ACTIVATE, show the MsgBox centered over Form1
    If lMsg = HCBT_ACTIVATE Then
       'Get the coordinates of the form and the message box so that
       'you can determine where the center of the form is located
       GetWindowRect Form1.hwnd, rectForm
       GetWindowRect wParam, rectMsg
       
       x = (rectForm.Left + (rectForm.Right - rectForm.Left) / 2) - ((rectMsg.Right - rectMsg.Left) / 2)
       y = (rectForm.Top + (rectForm.Bottom - rectForm.Top) / 2) - ((rectMsg.Bottom - rectMsg.Top) / 2)
       'Position the msgbox
       SetWindowPos wParam, 0, x, y, 0, 0, SWP_NOSIZE Or SWP_NOZORDER Or SWP_NOACTIVATE
       'Release the CBT hook
       UnhookWindowsHookEx hHook
       
    End If
   
    WinProc2 = False

End Function

Esto en un Command1 y Command2

Código: [Seleccionar]

Private Sub Command1_Click()
   
    Dim hInst As Long
    Dim Thread As Long
   
    'Set up the CBT hook
    hInst = GetWindowLong(Me.hwnd, GWL_HINSTANCE)
    Thread = GetCurrentThreadId()
    hHook = SetWindowsHookEx(WH_CBT, AddressOf WinProc1, hInst, Thread)
   
    'Display the message box
    MsgBox "This message box has been positioned at (0,0)."

End Sub

Private Sub Command2_Click()
    Dim hInst As Long
    Dim Thread As Long
   
    'Set up the CBT hook
    hInst = GetWindowLong(Me.hwnd, GWL_HINSTANCE)
    Thread = GetCurrentThreadId()
    hHook = SetWindowsHookEx(WH_CBT, AddressOf WinProc2, hInst, Thread)
   
    'Display the message box
    MsgBox "This message box is centered over Form1."
End Sub


[YAcosta]

Bestial!!! Funciona bien, al principio no sabia como modificar las coordenadas pero ya lo encontre. Gracias doc.

[ssccaann43]

En un Modulo esto:

Código: [Seleccionar]

Type RECT
   Left As Long
   Top As Long
   Right As Long
   Bottom As Long
End Type

Public Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Public Declare Function GetCurrentThreadId Lib "kernel32" () As Long
Public Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
Public Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Public Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long

Public Const GWL_HINSTANCE = (-6)
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOZORDER = &H4
Public Const SWP_NOACTIVATE = &H10
Public Const HCBT_ACTIVATE = 5
Public Const WH_CBT = 5

Public hHook As Long

Function WinProc1(ByVal lMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

   If lMsg = HCBT_ACTIVATE Then
      'Show the MsgBox at a fixed location (0,0)

      'ACA LE CAMBIAS LA POSICION EL 100 Y EL 200 ES

      SetWindowPos wParam, 0, 100, 200, 0, 0, SWP_NOSIZE Or SWP_NOZORDER Or SWP_NOACTIVATE
      'Release the CBT hook
      UnhookWindowsHookEx hHook
   End If
   WinProc1 = False

End Function

Function WinProc2(ByVal lMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

    Dim rectForm As RECT, rectMsg As RECT
    Dim x As Long, y As Long
   
    'On HCBT_ACTIVATE, show the MsgBox centered over Form1
    If lMsg = HCBT_ACTIVATE Then
       'Get the coordinates of the form and the message box so that
       'you can determine where the center of the form is located
       GetWindowRect Form1.hwnd, rectForm
       GetWindowRect wParam, rectMsg
       
       x = (rectForm.Left + (rectForm.Right - rectForm.Left) / 2) - ((rectMsg.Right - rectMsg.Left) / 2)
       y = (rectForm.Top + (rectForm.Bottom - rectForm.Top) / 2) - ((rectMsg.Bottom - rectMsg.Top) / 2)
       'Position the msgbox
       SetWindowPos wParam, 0, x, y, 0, 0, SWP_NOSIZE Or SWP_NOZORDER Or SWP_NOACTIVATE
       'Release the CBT hook
       UnhookWindowsHookEx hHook
       
    End If
   
    WinProc2 = False

End Function

Esto en un Command1 y Command2

Código: [Seleccionar]

Private Sub Command1_Click()
   
    Dim hInst As Long
    Dim Thread As Long
   
    'Set up the CBT hook
    hInst = GetWindowLong(Me.hwnd, GWL_HINSTANCE)
    Thread = GetCurrentThreadId()
    hHook = SetWindowsHookEx(WH_CBT, AddressOf WinProc1, hInst, Thread)
   
    'Display the message box
    MsgBox "This message box has been positioned at (0,0)."

End Sub

Private Sub Command2_Click()
    Dim hInst As Long
    Dim Thread As Long
   
    'Set up the CBT hook
    hInst = GetWindowLong(Me.hwnd, GWL_HINSTANCE)
    Thread = GetCurrentThreadId()
    hHook = SetWindowsHookEx(WH_CBT, AddressOf WinProc2, hInst, Thread)
   
    'Display the message box
    MsgBox "This message box is centered over Form1."
End Sub


Que bueno esta esto...! =)