como puedo leer un txt alojada en una web

[..::Carlos::..]

hola mi pregunta es haber si me pueden ayudar como puedo leer un txt alojada en una web y que me aparesca en un listbox o un testbox gracias espero su respuesta

[m[a]rkus]

Crea un Modulo

Código: [Seleccionar]

Private Declare Function InternetOpen Lib "wininet" Alias "InternetOpenA" (ByVal sAgent As String, ByVal lAccessType As Long, ByVal sProxyName As String, ByVal sProxyBypass As String, ByVal lFlags As Long) As Long
Private Declare Function InternetOpenUrl Lib "wininet" Alias "InternetOpenUrlA" (ByVal hInternetSession As Long, ByVal lpszUrl As String, ByVal lpszHeaders As String, ByVal dwHeadersLength As Long, ByVal dwFlags As Long, ByVal dwContext As Long) As Long
Private Declare Function InternetReadFile Lib "wininet" (ByVal hFile As Long, ByVal sBuffer As String, ByVal lNumBytesToRead As Long, lNumberOfBytesRead As Long) As Integer
Private Declare Function InternetCloseHandle Lib "wininet" (ByVal hInet As Long) As Integer
Private Const INTERNET_OPEN_TYPE_DIRECT As Long = 1
Private Const INTERNET_FLAG_RELOAD = &H80000000

Private Function GET_(hURL As String, Optional hUserAgent As String = "Mozilla Firefox") As String
 
    Dim hInternet    As Long
    Dim hFile        As Long
    Dim hBuffer      As String * 1000
    Dim hRead        As Long
 
    hInternet = InternetOpen(hUserAgent, INTERNET_OPEN_TYPE_DIRECT, vbNullString, vbNullString, 0)
   
        If hInternet <> 0 Then
           
            hFile = InternetOpenUrl(hInternet, hURL, vbNullString, ByVal 0&, INTERNET_FLAG_RELOAD, ByVal 0&)
           
                 If hFile <> 0 Then
                   
                    Do
                       Call InternetReadFile(hFile, hBuffer, 1000, hRead)
                       
                       GET_ = GET_ & Left$(hBuffer, hRead)

                       If hRead = 0 Then Exit Do
                       
                       DoEvents
                       
                    Loop
                 
                 End If
        End If
       
        If hInternet <> 0 Then Call InternetCloseHandle(hInternet)
        If hFile <> 0 Then Call InternetCloseHandle(hFile)

End Function

En el Form

1- textbox

Código: [Seleccionar]

Private Sub Form_Load()
Text1.text = GET_("http://www.google.es")
End Sub

[..::Carlos::..]

gracias m[a]rkus por tu tiempo