InnoSetup y ConectorODBC MySQL

[E N T E R]

Hola Raul estaba siguien este aporte que proporcionaste en otro web.
http://www.vb-mundo.com/crear-instalador-coninnosetup/

Pero tengo un problema con el ConectorODBC MySQL, registra todo lo que tiene que registrar en el windows pero al iniciar mi programa me dice que el odbc no se encuentra.

Este es mi Scrip de InnoSetup

Código: (PHP) [Seleccionar]

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
       
AppId={{54C00062-93FD-49E4-9368-66AE46D3AF5B}}
AppName=Alumnos.exe
AppVersion=1.0
AppPublisher=GESTION ALUMNOS v1.0
AppPublisherURL=http://www.enterpy.com/
AppSupportURL=http://www.enterpy.com/
AppUpdatesURL=http://www.enterpy.com/
DefaultDirName={pf}\Alumnos
DefaultGroupName=GESTION ALUMNOS v1.0
AllowNoIcons=yes
OutputDir=C:\appSetup\
;OutputBaseFilename=setup
Compression=lzma2
SolidCompression=yes
ShowLanguageDialog=no
PrivilegesRequired=admin

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"
Name: "spanish"; MessagesFile: "compiler:Languages\Spanish.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}";

[Files]

;Datos del programa
Source: "c:\appSetup\soft\alumnos.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "c:\appSetup\soft\alumnos.sql"; DestDir: "{app}"; Flags: ignoreversion
Source: "c:\appSetup\soft\recibo.xls"; DestDir: "{app}"; Flags: ignoreversion
Source: "c:\appSetup\soft\logo.jpg"; DestDir: "{app}"; Flags: ignoreversion

;Runtime de VB6
Source: "c:\appSetup\runtime\MSCOMCTL.OCX"; DestDir: "{app}\"; Flags: uninsneveruninstall sharedfile regserver
Source: "c:\appSetup\runtime\mscomct2.ocx"; DestDir: "{app}\"; Flags: uninsneveruninstall sharedfile regserver
Source: "c:\appSetup\runtime\comdlg32.ocx"; DestDir: "{app}\"; Flags: uninsneveruninstall sharedfile regserver

Source: "c:\appSetup\runtime\stdole2.tlb";  DestDir: "{sys}"; OnlyBelowVersion: 0,6; Flags: restartreplace uninsneveruninstall sharedfile regtypelib
Source: "c:\appSetup\runtime\msvbvm60.dll"; DestDir: "{sys}"; OnlyBelowVersion: 0,6; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "c:\appSetup\runtime\oleaut32.dll"; DestDir: "{sys}"; OnlyBelowVersion: 0,6; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "c:\appSetup\runtime\olepro32.dll"; DestDir: "{sys}"; OnlyBelowVersion: 0,6; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "c:\appSetup\runtime\asycfilt.dll"; DestDir: "{sys}"; OnlyBelowVersion: 0,6; Flags: restartreplace uninsneveruninstall sharedfile
Source: "c:\appSetup\runtime\comcat.dll";   DestDir: "{sys}"; OnlyBelowVersion: 0,6; Flags: restartreplace uninsneveruninstall sharedfile regserver

;Fuente que usa mi aplicacion a veces el WinXP no lo tiene
Source: "c:\appSetup\fonts\consola.ttf"; DestDir: {fonts}; Flags: onlyifdoesntexist uninsneveruninstall; FontInstall: consola
Source: "c:\appSetup\fonts\consolab.ttf"; DestDir: {fonts}; Flags: onlyifdoesntexist uninsneveruninstall; FontInstall: consolab
Source: "c:\appSetup\fonts\consolai.ttf"; DestDir: {fonts}; Flags: onlyifdoesntexist uninsneveruninstall; FontInstall: consolai
Source: "c:\appSetup\fonts\consolaz.ttf"; DestDir: {fonts}; Flags: onlyifdoesntexist uninsneveruninstall; FontInstall: consolaz

;ODBCs MySQL - 32 bits

Source: "c:\appSetup\odbc\32bits\myodbc5.lib"; DestDir: "{sys}"; Check: not Is64BitInstallMode; Flags: sharedfile uninsneveruninstall
Source: "c:\appSetup\odbc\32bits\myodbc5S.lib"; DestDir: "{sys}"; Check: not Is64BitInstallMode; Flags: sharedfile uninsneveruninstall
Source: "c:\appSetup\odbc\32bits\myodbc5.dll"; DestDir: "{sys}"; Check: not Is64BitInstallMode; Flags: sharedfile uninsneveruninstall
Source: "c:\appSetup\odbc\32bits\myodbc5S.dll"; DestDir: "{sys}"; Check: not Is64BitInstallMode; Flags: sharedfile uninsneveruninstall
Source: "c:\appSetup\odbc\32bits\myodbc3.hlp"; DestDir: "{sys}"; Check: not Is64BitInstallMode; Flags: sharedfile uninsneveruninstall
Source: "c:\appSetup\odbc\32bits\myodbc-installer.exe"; DestDir: "{sys}"; Check: not Is64BitInstallMode; Flags: sharedfile uninsneveruninstall


[Icons]
Name: "{group}\Alumnos"; Filename: "{app}\Alumnos.exe"
Name: "{group}\Visitano en: "; FileName: "http://www.enterpy.com/"
Name: "{group}\{cm:UninstallProgram,MyAPP}"; FileName: "{uninstallexe}"
Name: "{commondesktop}\Alumnos"; FileName: "{app}\Alumnos.exe"; Tasks: desktopicon

[raul338]

Porque te faltan las lineas del Run, vos copias los archivoa al sistema pero jamas lo registrar, lo que te falta es esto:

Código: [Seleccionar]

[Run]
FileName: "{sys}\myodbc-installer.exe"; Parameters:"-d -a -n ""MySQL ODBC 5.1 Driver"" -t ""DRIVER=myodbc5.dll;SETUP=myodbc5S.dll"" ";StatusMsg: "Registrando MySQL...";

[E N T E R]

Exacto Raul se me escapo ese, te agradezco

[E N T E R]

Raul como hago para crear un acceso directo de mi programa para que inicie cada ves que arranque la pc

Aca quiero crear un acceso directo.

[raul338]

Va en la parte Icons, más info en la documentacion (exactamente aca)

Código: [Seleccionar]

[Icons]
Name: ""{commonstartup}\My Program""; Filename: "{app}\MYPROG.EXE"; WorkingDir: "{app}"