[SOLUCIONADO] ListView Mover Filas

[VanHan]

Hola foro, como dice el título como se puede hacer para subir y bajar filas o posicionar filas debajo de alguna otra fila específica.

Salu2
[vHn]

[LeandroA]

Hola lo que se hace es intercambiar los valores de un item y otro, (esa es una forma o bien insertar y eliminar pero no es mejor)

Un ejemplo intercamibando valores

Código: (vb) [Seleccionar]

Private Sub SubirItem()
    Dim sTemp As String
    Dim Item As ListItem
    Dim PrevItem As ListItem
    Dim i As Long
   
    Set Item = ListView1.SelectedItem
   
    If Item.Index = 1 Then Exit Sub
   
    Set PrevItem = ListView1.ListItems(Item.Index - 1)
   
    sTemp = Item.Text
    Item.Text = PrevItem.Text
    PrevItem.Text = sTemp
   
    For i = 1 To ListView1.ColumnHeaders.Count - 1
        sTemp = Item.SubItems(i)
        Item.SubItems(i) = PrevItem.SubItems(i)
        PrevItem.SubItems(i) = sTemp
    Next
   
    PrevItem.Selected = True

End Sub

Private Sub BajarItem()
    Dim sTemp As String
    Dim Item As ListItem
    Dim NextItem As ListItem
    Dim i As Long
   
    Set Item = ListView1.SelectedItem
   
    If Item.Index = ListView1.ListItems.Count Then Exit Sub
   
    Set NextItem = ListView1.ListItems(Item.Index + 1)
   
    sTemp = Item.Text
    Item.Text = NextItem.Text
    NextItem.Text = sTemp
   
    For i = 1 To ListView1.ColumnHeaders.Count - 1
        sTemp = Item.SubItems(i)
        Item.SubItems(i) = NextItem.SubItems(i)
        NextItem.SubItems(i) = sTemp
    Next
   
    NextItem.Selected = True

End Sub


[VanHan]

Lea, supongamos q yo tengo en mi listview, un subitem, q tiene este texto: "#####" y q lo quiero detectar por medio de un For, y a este subirlo 3 filas.... q idea me podes dar... sin usar SELECTITEM, gracias de todas formas espero las respuesta

Salu2
[vHn]

[wolf_kof]

  vanhan que rayos estas haciendo para tener semejante problema con un simple listview

[LeandroA]

hola para hacer refencia a un item especifico utiliza ListView1.ListItems(elindexquequieras)

creo que con eso basta despues ponete a jugar un rato con lo que te puse al principio y vas a ir acomodandolo a tu nesecidad.

Saludos.

[VanHan]

Gracias a ambos!!! ya lo solucione 

PD: Me meti en un lío solo, y son de esos lios q solo tu te metes y hasta q te das cuenta q era mucho mas facil de otra forma, jejeje...

Salu2
[vHn]