Visual Basic Foro

Hola colega fezaca 

Agrega dos textbox y un combobox (TextBox1,TextBox2,ComboBox1)

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Agregar_Combo()
    End Sub

    Private Sub Agregar_Combo()
        ComboBox1.DisplayMember = "nombre"
        ComboBox1.ValueMember = "id"
        ComboBox1.DataSource = Obtener_Datos()
    End Sub


    Private Function Obtener_Datos() As DataTable
        Dim Dt As New DataTable
        Dim Dr As DataRow

        'aca pongo esto como para tener unos datos en el datatable
        'podrían ser los datos directos de tu BDD

        Dt.Columns.Add(New DataColumn("id", GetType(Integer)))
        Dt.Columns.Add(New DataColumn("nombre", GetType(String)))

        Dr = Dt.NewRow()
        Dr("id") = 10
        Dr("nombre") = "pepe"
        Dt.Rows.Add(Dr)

        Dr = Dt.NewRow()
        Dr("id") = 20
        Dr("nombre") = "juan"
        Dt.Rows.Add(Dr)

       
        Dt.AcceptChanges()

        Return Dt
    End Function

    Private Sub ComboBox1_SelectedValueChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles ComboBox1.SelectedValueChanged
        TextBox1.Text = ComboBox1.Text
        TextBox2.Text = ComboBox1.SelectedValue
    End Sub
End Class

Espero te sirva ... salu2

Hola Enter ... te defino a función que pides ...

Private Function Recibir_mensaje(ByVal Tipo As Tipo) As String

Enum Tipo
        SMS_NO_LEIDOS
        SMS_LEIDOS
        SMS_NO_ENVIADOS
        SMS_ENVIADOS
        SMS_TODOS
    End Enum
    Private Function Recibir_mensaje(ByVal Tipo As Tipo) As String
        Try
            SerialPort1.Write("ATZ&F" & Chr(13))
            SerialPort1.Write("AT+CMGF=1" & Chr(13)) 'este comando establece el modo texto

            Select Case Tipo
                Case Form1.Tipo.SMS_NO_LEIDOS
                    SerialPort1.Write("AT+CMGL=" & Chr(34) & "REC UNREAD" & Chr(34) & Chr(13)) 'solo recibiremos los sms no leidos
                Case Form1.Tipo.SMS_LEIDOS
                    SerialPort1.Write("AT+CMGL=" & Chr(34) & "REC READ" & Chr(34) & Chr(13)) 'solo recibiremos los sms leidos
                Case Form1.Tipo.SMS_NO_ENVIADOS
                    SerialPort1.Write("AT+CMGL=" & Chr(34) & "STO UNSENT" & Chr(34) & Chr(13)) 'solo recibiremos los sms no enviados
                Case Form1.Tipo.SMS_ENVIADOS
                    SerialPort1.Write("AT+CMGL=" & Chr(34) & "STO SENT" & Chr(34) & Chr(13)) 'solo recibiremos los sms enviados
                Case Form1.Tipo.SMS_TODOS
                    SerialPort1.Write("AT+CMGL=" & Chr(34) & "ALL" & Chr(34) & Chr(13)) 'Recibiremos todos los sms

            End Select
            Recibir_mensaje = vbOK
        Catch ex As Exception
            Recibir_mensaje = ex.Message
        End Try
    End Function
Hola Jerónimo

no sé si se necesita un modem especial

Puedes usar cualquier módem gsm ... (puede que tengas un módem gsm a mano como son los módem claro y movistar que se usan para conectividad de internet o simplemente tu celular ... con el tema del celular puedes tener algunos  inconveniente dependiendo de la marca y modelo ...  )

Y como dice el colega Waldo

Si, si un simcard comun y silvestre como el de cualquier telefono

Esto tiene muchas aplicaciones. Se puede implementar en Desarrollos en donde automáticamente se envíen mensajes individuales o masivos para diferentes propósitos ....

Publicidades, estados de deudas, etc ...

Pero esto es potenciado con la capacidad de recibir y procesar los mensajes recibidos ... ya que mediante ellos se puede tener una conversación automatizada con el emisor ... ejemplo ... ampliaciones de servicios, selección de opciones, códigos de alertas,etc

Creo que ampliaré un poco mas con un ejemplo, consigan un módem claro, este tipo módem trae los driver contenidos en el mismo ...  ya estaré subiendo un ejemplo ... salu2 colegas

Hola a todos los Colegas ...
 
aquí quiero mostrarles una función que les permitirá construir la consulta SQL necesaria para realizar una búsqueda de datos.

Hay funciones especificas según el motor de base de datos utilizado, que resolverían esto de manera mas eficiente, algunos sujetos a pre-configuraciones.

Esta función nos permite independizar nuestro desarrollo de una base de datos específica

El tema de un buscador es no complicar al cliente con muchas opciones, simplemente que encuentre los datos de manera eficiente ...

Esta función permite establecer en forma descentralizada algunas opciones en la búsqueda, ideal para considerarla dentro de un módulo como pública ...

Primero se ingresan los datos a buscar, estos son de l estilo "gaseosa cola 2l", es decir que el espacio implicará el final y el comienzo de una cadena para la búsqueda

Luego se ingresan en los campos que deseamos buscar, separando cada nombre de campo con un caracter determinado, en este caso usé el "|"

asi que por ejemplo sería --- "codigo|descripcion|proveedor" --- > significa que se buscarán coincidencias en esos tres campos al mismo tiempo o por separado, ya explico mas adelante


Establecemos la tabla correspondiente "tb_articulos"

La próxima opción sería in índice, el cual al ingresar 0 (cero), permitirá buscar de manera simultánea en todos los campos ingresados

codigo   descripcion   proveedor

pero si colocamos por ejemplo 1, solo buscará coincidencias con el campo "codigo", si es 2 "descripcion" y así sucesivamente

Ahora bién esto nos permitiría construir opciones de búsquedas, por ejemplo:

0- Búsqueda general        (buscar en todos los campos)
--------------------------
1- Búscar por código
2- Búscar por descripción
3- Búscar por proveedor

Por último, como no podía faltar una compuerta lógica ... la cual puede ser muy discutible, ya que muchos optarán por implementar caracteres especiales para esto como "(+)" o bién palabras como "AND" y "OR", pero permitan expresar mi humilde opinión sobre esto, en mi experiencia como desarrollador, he notado que las personas solo utilizan el sistema de búsqueda "O", similar a lo que realizan con el buscador google, sin prefijos ni nada por el estilo, solo en casos muy especiales un usuario requiere una "Y" ... vendrán a la mente muchas opciones en donde podríamos implementar una lógica "Y", pero sinceramente, la necesidad de usar esta lógica dependerá mucho de la cantidad de datos contenidos en la base de datos, que puedan coincidir en dos o tres muestras de cadenas de búsqueda. A pesar de esto solo será relevante dependiendo de la cantidad de resultados que obtengamos en dicha búsqueda, ya que pueden ser pocos y de fácil visualización, es decir, si volvemos al ejemplo anterior:

"gaseosa cola 2l"

supongo que si ponemos "gaseosa" apareceran mas coincidencias que en "gaseosa cola 2l", y estas coincidencias disminuirán  de manera rigurosa si por ejemplo agregamos una marca o un código, ejemplos


"coca cola 2l"

Es más fácil para el usuario establecer una "forma" (quizás en el cargado de un artículo) para una búsqueda eficiente, que recordar la manera o que opciones debería seleccionar para buscar cada artículo, y obtener la menor cantidad de resultados posible, se comprende?

Pero bueno el tema es que existe la lógica "AND" y "OR" de manera "generalizada" dentro de la función y si se desea se puede agregar como opción, mediante false para "OR" y true para "AND"

Dependiendo del motor utilizado (ej. caso mysql, si se codifica la base de datos correctamente), seguramente no habrá inconvenientes con LIKE, en cuanto a acentos. Tampoco hará distinción entre mayúsculas o minúsculas. Pero siempre hay que recordar las funciones SQL UPPER(), REPLACE(), LOWER() si se requiere por algún motivo acomodar la función a nuestras necesidades.

Bueno entonces la función sería:



Dim sDatos as string = "cadena1 cadena2 cadena3"

fBuscador(sDatos, "codigo|descripcion|proveedor", "tb_articulos", 0, false)

Imports System.Text
    Function fBuscador(ByVal sDato As String, ByVal sCampos As String, ByVal sTabla As String, ByVal iIndiceCampo As Integer, ByVal bLogica As Boolean) As String
        'BY SOFTMANIA
        Dim sDatos As New StringBuilder
        Dim sSplitDatos() As String = sDato.Split(" ")
        Dim sSplitCampos() As String = sCampos.Split("|")
        Dim bVerifica As Boolean
        Dim iCont As Integer
        Dim iCantCampos As Integer

        sDatos.Append("SELECT " & sTabla & ".* FROM " & sTabla & " WHERE ")

        iCantCampos = UBound(sSplitCampos)

        For Each sSplitCampo As String In sSplitCampos
            iCont = iCont + 1
            If iIndiceCampo = iCont Or iIndiceCampo = 0 Then

                bVerifica = False

                For Each sSplitDato As String In sSplitDatos

                    If bLogica = False Then
                        If bVerifica = False Then
                            sDatos.Append("(" & sTabla & "." & sSplitCampo & " LIKE '%" & sSplitDato & "%'")
                            bVerifica = True
                        Else
                            sDatos.Append(" OR " & sTabla & "." & sSplitCampo & " LIKE '%" & sSplitDato & "%'")
                        End If
                    Else
                        If bVerifica = False Then
                            sDatos.Append("(" & sTabla & "." & sSplitCampo & " LIKE '%" & sSplitDato & "%'")
                            bVerifica = True
                        Else
                            sDatos.Append(" AND " & sTabla & "." & sSplitCampo & " LIKE '%" & sSplitDato & "%'")
                        End If
                    End If
                Next
                If iIndiceCampo = 0 And iCantCampos > 0 And iCantCampos > iCont - 1 Then
                    sDatos.Append(") OR ")
                Else
                    sDatos.Append(")")
                End If
            End If
        Next
        sDatos.Append(";")
        Return sDatos.ToString
    End Function

Mucha explicación para una función tan simple y básica, pero la idea es abrir el debate 

Salu2 COLEGAS

Hola a todos ...

Aquí les dejo como hacer un split con varios separadores

 
        Dim sCadena As String
        Dim sResultado As String = ""
        Dim sSplit() As String
        'cargamos una cadena de nombres y variamos los separadores
        sCadena = "pablo;juan;pedro|marcos;miguel|jorge"
        'en el split especificamos que carateres serán utilizados como separador
        'en este caso ";" y "|"
        sSplit = sCadena.Split(New [Char]() {";", "|"})
        'y mostramos el resultado
        For Each sResulFor As String In sSplit
            sResultado = sResultado + sResulFor + vbNewLine
        Next
        MsgBox(sResultado)
   

  No es algo muy común de utilizar, pero en algún momento pueden necesitarlo ...

      salu2 a todos

Esta función permite verificar si el CUIT ingresado es correcto

  Public Function VerificacionCuit(ByVal sValor As String) As Boolean
        Dim sValorNeto As String
        Dim iSuma As Integer
        Dim iResto As Integer
        Dim iVerificador As Integer
        Dim iVerificadorCadena As Integer
        Dim iValorMaTrizConst() As Integer = {5, 4, 3, 2, 7, 6, 5, 4, 3, 2}
        Dim iCont As Integer
        'by softmania
        'Quitamos los caracteres que no usaremos
        sValorNeto = sValor.Replace("-", "").ToString
        'sValorNeto = Valor.Replace("/", "").ToString

        Try
            'verificamos que sean 11 dígitos
            If sValorNeto.Length <> 11 Then Return False : Exit Function
            'separamos el dígito verificador del resto de los números
            iVerificadorCadena = CInt(sValorNeto.Substring(10, 1).ToString)
            'separamos todos los números del dígito verficador
            sValorNeto = sValorNeto.Substring(0, 10).ToString

            For iCont = 0 To 9
                'aquí se suman las multiplicaciones de cada dígito por cada número contenido en la matríz
                'ejemplo 20-28175331-1
                'sería
                '  2   0   2    8   1    7    5    3   3   1
                'X
                '  5   4   3    2   7    6    5    4   3   2
                '-------------------------------------------
                ' 10 + 0 + 6 + 16 + 7 + 42 + 25 + 12 + 9 + 2 =  129

                iSuma = iSuma + (CInt(sValorNeto.Substring(iCont, 1)) * iValorMaTrizConst(iCont))

            Next
            ' Obtenermos el resto de la suma dividida 11
            iResto = iSuma Mod 11


            'Según el resto obtenido calculamos el dígito verificador
            If iResto = 0 Then
                iVerificador = 0
            ElseIf iResto = 1 Then
                iVerificador = 9
            Else
                iVerificador = 11 - iResto
            End If

            'comparamos el dígito verificador obtenido con el dígito de verificación ingresado
            'establecemos si la función devuelve false o true según corresponda
            If iVerificador = iVerificadorCadena Then
                Return True

            Else
                Return False

            End If

        Catch ex As Exception
            Return False
        End Try

    End Function

Hola a todos ... aquí les dejo una clase para enviar correos.
La clase lo único que hace es ordenar un poco.
Las clases System.Net.Mail.MailMessage y System.Net.Mail.SmtpClient son excelentes y fácil de usar en forma directa

Public Class cMail

#Region "INTRO"

    'Clase creada por SoftMania
    'Aplicación: Clase para envíar correos

    'Declarar clase
    'Dim Correo As New cMail

    'Modo de implementación

    'Los nombres son intuitivos ----------------------------------------------------------------

    '   Correo.pServidorCorreo = "smtp.gmail.com"
    '   Correo.pPuertoCorreo = 587
    '   Correo.pHabilitarSsl = True                         'conexión segura si fuera requerido
    '   Correo.pUsuario = "correo_origen@xxxx.com"          'usuario del correo
    '   Correo.pPassWord = "xxxxx"                          'pass del correo
    '   Correo.pCodificacion = cMail.eCodificacion.UTF8
    '   Correo.pCorreoRemitente = "correo_origen@xxxx.com"  'el que envía :P
    '   Correo.pCorreoDestino = "correo_destino@xxxx.com"   'el que recine :P
    '   Correo.pApodo = "PEPE"
    '   Correo.pAsunto = "AQUI EL ASUNTO"
    '   Correo.pMensaje = "AQUI EL MENSAJE"
    '   Correo.pFormatoHtml = True
    '   Correo.pPrioridad = cMail.ePrioridad.NORMAL
    '   Correo.Enviar_correo()
    '-------------------------------------------------------------------------------------------
#End Region

#Region "DECLARACION"
    Dim sCorreoRemitente As String
    Dim sServidorCorreo As String = "smtp.gmail.com"
    Dim sPuertoCorreo As Integer = 587
    Dim sHabilitarSsl As Boolean = True
    Dim sCorreoDestino As String
    Dim sAsunto As String
    Dim sMensaje As String
    Dim sPrioridad As ePrioridad = ePrioridad.NORMAL
    Dim sCodificacion As eCodificacion = eCodificacion.UTF8
    Dim sUsuario As String
    Dim sPassWord As String
    Dim sApodo As String
    Dim sFormatoHtml As Boolean = True
    Enum eCodificacion
        UTF8
        UTF32
        UTF7
        ASCII
    End Enum
    Enum ePrioridad
        ALTA
        NORMAL
        BAJA
    End Enum
#End Region
#Region "PROPIEDADES"
    Public Property pFormatoHtml() As String
        Get
            Return sFormatoHtml
        End Get
        Set(ByVal value As String)
            sFormatoHtml = value
        End Set
    End Property
    Public Property pUsuario() As String
        Get
            Return sUsuario
        End Get
        Set(ByVal value As String)
            sUsuario = value
        End Set
    End Property
    Public Property pApodo() As String
        Get
            Return sApodo
        End Get
        Set(ByVal value As String)
            sApodo = value
        End Set
    End Property
    Public Property pPassWord() As String
        Get
            Return sPassWord
        End Get
        Set(ByVal value As String)
            sPassWord = value
        End Set
    End Property
    Public Property pPrioridad() As ePrioridad
        Get
            Return sPrioridad
        End Get
        Set(ByVal value As ePrioridad)
            sPrioridad = value
        End Set
    End Property
    Public Property pCodificacion() As eCodificacion
        Get
            Return sCodificacion
        End Get
        Set(ByVal value As eCodificacion)
            sCodificacion = value
        End Set
    End Property
    Public Property pMensaje() As String
        Get
            Return sMensaje
        End Get
        Set(ByVal value As String)
            sMensaje = value
        End Set
    End Property
    Public Property pAsunto() As String
        Get
            Return Me.sAsunto
        End Get
        Set(ByVal value As String)
            Me.sAsunto = value
        End Set
    End Property
    Public Property pCorreoDestino() As String
        Get
            Return Me.sCorreoDestino
        End Get
        Set(ByVal value As String)
            Me.sCorreoDestino = value
        End Set
    End Property
    Public Property pHabilitarSsl() As Boolean
        Get
            Return Me.sHabilitarSsl
        End Get
        Set(ByVal value As Boolean)
            Me.sHabilitarSsl = value
        End Set
    End Property
    Public Property pPuertoCorreo() As Integer
        Get
            Return Me.sPuertoCorreo
        End Get
        Set(ByVal value As Integer)
            Me.sPuertoCorreo = value
        End Set
    End Property
    Public Property pServidorCorreo() As String
        Get
            Return Me.sServidorCorreo
        End Get
        Set(ByVal value As String)

            Me.sServidorCorreo = value
        End Set
    End Property
    Public Property pCorreoRemitente() As String
        Get
            Return Me.sCorreoRemitente
        End Get
        Set(ByVal value As String)
            Me.sCorreoRemitente = value
        End Set
    End Property
#End Region
#Region "FUNCIONES"
    Public Function Enviar_correo() As Boolean
        Dim rCodificacion As System.Text.Encoding
        Dim rPrioridad As System.Net.Mail.MailPriority
        Dim vMensaje As New System.Net.Mail.MailMessage
        Dim ServSMTP As New System.Net.Mail.SmtpClient
        ServSMTP.Host = sServidorCorreo
        ServSMTP.Port = sPuertoCorreo
        ServSMTP.EnableSsl = sHabilitarSsl
        ServSMTP.Credentials = New System.Net.NetworkCredential(sUsuario, sPassWord)
        vMensaje.[To].Add(sCorreoDestino) 'Cuenta de Correo al que se le quiere enviar el e-mail
        Select Case sCodificacion
            Case eCodificacion.ASCII
                rCodificacion = System.Text.Encoding.ASCII
            Case eCodificacion.UTF32
                rCodificacion = System.Text.Encoding.UTF32
            Case eCodificacion.UTF7
                rCodificacion = System.Text.Encoding.UTF7
            Case Else
                rCodificacion = System.Text.Encoding.UTF8
        End Select
        Select Case sPrioridad
            Case ePrioridad.ALTA
                rPrioridad = Net.Mail.MailPriority.High
            Case ePrioridad.BAJA
                rPrioridad = Net.Mail.MailPriority.Low
            Case ePrioridad.NORMAL
                rPrioridad = Net.Mail.MailPriority.Normal
        End Select
        vMensaje.From = New System.Net.Mail.MailAddress(sCorreoRemitente, sApodo, rCodificacion)
        vMensaje.Subject = sAsunto
        vMensaje.SubjectEncoding = rCodificacion
        vMensaje.Body = sMensaje
        vMensaje.BodyEncoding = rCodificacion
        vMensaje.IsBodyHtml = sFormatoHtml
        vMensaje.Priority = rPrioridad
        Try
            ServSMTP.Send(vMensaje)
            Return True
        Catch ex As System.Net.Mail.SmtpException
            Return False
        End Try
    End Function
#End Region
End Class
Ando con poco tiempo, me despido colegas ...  salu2 a todos 

Soy programador de .net, pero no migré porque hubiera algo que no haya podido hacer en vb6, solo por actualizarme. A través de él, pude aprender varios lenguajes en el camino, los cuales compartían mucho de su estructura, entre ellos el que mencionas, , visual movile, hb++ que es la contracara, de palm's y WIN CE. Así que entiendo tu sentimiento hacia vb6, jejejeje. Basic4Android es muy similar a vb6 en cuanto a código, es un poco precario en como fue diseñado en algunas cosas, que se yo, un ejemplo simple, en como se agregan los eventos, la declaración de los objetos ... etc, pero es muy potente. Cambian algunas cosas radicales, como es por ejemplo el conexionado a mysql, en donde ya interviene un poco de PHP, nada de otro mundo, pero que puede perder un poco a un usuario con poca experiencia. Salu2