Como envio informacion de un listbox al servidor

[..::Carlos::..]

hola a todo el foro me gustaria saber como puedo pasar toda la informacion que agrego a un listbox que se encuentra en el cliente y enviarlo al servidor y guardarla en un txt en el pc remoto
Gracias a todos

[BlackZeroX]

Sockets!¡.

Dulces Lunas!¡.

[..::Carlos::..]

si yo uso socket lo que pasa es no se como recivir los datos en el servidor apra que se guarde en el txt

[LeandroA]

Te paso un ejemplo muy muy basico sin comprobación de nada osea despues vos te encargas de aprender mas sobre sokets y como hacer el resto

codigo del servidor (tenes que agregar el componente "Microsoft Winsock control 6")

Código: (vb) [Seleccionar]

Option Explicit

Private Sub Form_Load()
    Winsock1.LocalPort = 100
    Winsock1.Listen
    Open "C:\archivo.txt" For Binary As #1
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Close #1
End Sub

Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long)
    Winsock1.Close
    Winsock1.Accept requestID
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
    Dim Data As String
    Winsock1.GetData Data
    Put #1, , Data
End Sub



Codigo del cliente  (tenes que agregar el componente "Microsoft Winsock control 6") un listbox y un commandButton

Código: (Vb) [Seleccionar]

Option Explicit

Private Sub Form_Load()
    Dim i As Long
    For i = 1 To 100
        List1.AddItem "Soy el item" & i
    Next
End Sub

Private Sub Command1_Click()
    Dim IPServidor As String
    IPServidor = "127.0.0.1" 'solo para probar localmente
    Winsock1.Connect IPServidor, 100
End Sub

Private Sub Winsock1_Connect()
    Dim i As Long
    For i = 0 To List1.ListCount
        Winsock1.SendData List1.List(i) & vbCrLf
    Next
End Sub

Private Sub Winsock1_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
    MsgBox Err.Description
End Sub
saludos.

[..::Carlos::..]

Muchas gracias